Added mongodb-3.4.23.

app-admin/mongo-tools/Manifest

@@ -1,2 +1,4 @@
 DIST mongo-tools-3.4.16.tar.gz 4697191 BLAKE2B 2e9a0e7dc8016d3e7d7c7f8d0cf80a97d3d199603c0b8b791df5a0d79d418ffaa232eee694047a7ca11fa7623023b4123becd437cfe3dec11e26cd525720bcad SHA512 b40c6dee75d860de1da73faf79f5f68c098ce7c80681486c66fff04a937474dcede91c7be907a8e36033b3898f7499e8f53271944c0df3360756c27361efb6f5
+DIST mongo-tools-3.4.23.tar.gz 4712212 BLAKE2B fc84e25696f12cab66fcf9f4f192b3f0e8a827598b6de2b80606c4d00da8134e200cc883626cd74bddcc208efd4e5c7046c1b4c69be12e0dbbb2df801bdc7be1 SHA512 1cfba67daf82837df2a27f8961f78bdcfcd7be57af66b34c090cdd6f385a38272680e5c4d9513b139cb18307576ce23663ae19b283ed92edbf1c5327043585e8
 EBUILD mongo-tools-3.4.16.ebuild 1191 BLAKE2B 0765a673d50d0d7c8a8dae14e28f5aa27f0bd5896273386700ea3a1e743514f248ed195208b0e4036ffddfe9955471cae138e03502d1e1a5405f5dba2f019663 SHA512 dcf2017a3bd22d0c45d99cf30810d4de6c577a9c9056df1bb2faf8c0466b1018444cb887b76f5711b30f845a9d46d4c03b8aac86be54aaf6d57c34b4715a613b
+EBUILD mongo-tools-3.4.23.ebuild 1191 BLAKE2B 0765a673d50d0d7c8a8dae14e28f5aa27f0bd5896273386700ea3a1e743514f248ed195208b0e4036ffddfe9955471cae138e03502d1e1a5405f5dba2f019663 SHA512 dcf2017a3bd22d0c45d99cf30810d4de6c577a9c9056df1bb2faf8c0466b1018444cb887b76f5711b30f845a9d46d4c03b8aac86be54aaf6d57c34b4715a613b

app-admin/mongo-tools/mongo-tools-3.4.23.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PV=${PV/_rc/-rc}
+MY_P=${PN}-r${MY_PV}
+
+DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
+HOMEPAGE="https://www.mongodb.com"
+SRC_URI="https://github.com/mongodb/mongo-tools/archive/r${MY_PV}.tar.gz -> mongo-tools-${MY_PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="sasl ssl"
+
+RDEPEND="!<dev-db/mongodb-3.0.0"
+DEPEND="${RDEPEND}
+	dev-lang/go:=
+	net-libs/libpcap
+	sasl? ( dev-libs/cyrus-sasl )
+	ssl? ( dev-libs/openssl:0= )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	# 1) ensure we use bash wrt #582906
+	# 2) do not substitute version because it uses git
+	sed -e 's@/bin/sh@/bin/bash@g' \
+		-e '/^sed/,+3d' \
+		-e '/^mv/d' \
+		-i build.sh || die
+
+	# build pie to avoid text relocations wrt #582854
+	# skip on ppc64 wrt #610984
+	if ! use ppc64; then
+		sed -i 's/\(go build\)/\1 -buildmode=pie/g' build.sh || die
+	fi
+}
+
+src_compile() {
+	local myconf=()
+
+	if use sasl; then
+		myconf+=(sasl)
+	fi
+
+	if use ssl; then
+		myconf+=(ssl)
+	fi
+
+	./build.sh "${myconf[@]}" || die "build failed"
+}
+
+src_install() {
+	dobin bin/*
+}

dev-db/mongodb/Manifest

@@ -2,4 +2,6 @@ AUX mongodb-3.4.0-fix-scons.patch 1411 BLAKE2B 6e5975b70ec7f281ea2cd101b16ee2849
 AUX mongodb-3.4.6-sysmacros-include.patch 1419 BLAKE2B f07ab093f13ea2b9675538dc99e2e58f85019edffad05bbbf3032f85f8ef881020cc9bf25bc62ca13344e7b8b7dd3b04954c76974c512a41ea5a7a2045de2b34 SHA512 ab269ec003b74848f981021f5eb09e38216d75dd9d1b8a155068b2a335d9ec9d1f5f575028ae9b4b0d8745d15e464cb05b70aabc6c28c984115574c6747afc05
 AUX mongodb-3.4.7-no-boost-check.patch 641 BLAKE2B 0dc3a426b28cd80d7b3361ff9c6747aff64dd27c1bc01a9717c2dd1c160b66f53feb72fd2ead385c220ebe92a8c7b8fa6b04fb3fa8437dba17d5f8346665f6b8 SHA512 812eaaadb6f265cfc904e8f3a7ae8276e42e3968529914179efab5e44f1951ab46ac3bbcfb259f924b20a8ca61d2ebcf72b7103ea9d5f25594ff8e9e3e85836b
 DIST mongodb-src-r3.4.16.tar.gz 40093657 BLAKE2B 7123444dbdd0b2ad3adfb3391e0177d33c1b6c6a4ea83027821c564faad047a736e52926bc15c58bef59c18282436e913fd3bc9963705e030da01356f83ea367 SHA512 e22eb1fe2a832fed8305200614988c5ecfd619cee44fe2263bffa151732c0e26584084e64065dbc65152be6e5c1767a538193770359bea92f3703c72239075db
+DIST mongodb-src-r3.4.23.tar.gz 40176687 BLAKE2B 1db9a2a9f409facb25e5fe2d481b757d9baaf2afccbb5a48aef6cf9e2a7a7d256c55faa7ccd0c1fef302703b88772a42a8b155deb70a08f2a99ae94779569b19 SHA512 01931d3701a9ed3109132cf3106a6f959f3a393e71284537959095f853cdad5c8b17eebddd4dc1d6a8cb4f5af8393b0bda62034318aa78fd5f656589449f7eb4
 EBUILD mongodb-3.4.16.ebuild 4085 BLAKE2B 2dad9e885c427855e4fe77da32e7141b16b17b3d5555a1e3e118279f95d80297fe0d6829a6bc19d3d3edfdf388ee9ff2f1fd925508d3b8b985f569500d2f95f2 SHA512 3b70f4a271a9fe41d9d384289c5812bd4abbd60b811a49909882c2e684b65de31f39a5b84320fed28795eb376c33fa2291ec0dc068b34229a6d255b73ee62922
+EBUILD mongodb-3.4.23.ebuild 4085 BLAKE2B 2dad9e885c427855e4fe77da32e7141b16b17b3d5555a1e3e118279f95d80297fe0d6829a6bc19d3d3edfdf388ee9ff2f1fd925508d3b8b985f569500d2f95f2 SHA512 3b70f4a271a9fe41d9d384289c5812bd4abbd60b811a49909882c2e684b65de31f39a5b84320fed28795eb376c33fa2291ec0dc068b34229a6d255b73ee62922

dev-db/mongodb/mongodb-3.4.23.ebuild

@@ -0,0 +1,160 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+SCONS_MIN_VERSION="2.3.0"
+CHECKREQS_DISK_BUILD="2400M"
+CHECKREQS_DISK_USR="512M"
+CHECKREQS_MEMORY="1024M"
+
+inherit check-reqs eapi7-ver eutils flag-o-matic multilib multiprocessing pax-utils python-single-r1 scons-utils systemd toolchain-funcs user
+
+MY_P=${PN}-src-r${PV/_rc/-rc}
+
+DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
+HOMEPAGE="https://www.mongodb.com"
+SRC_URI="https://fastdl.mongodb.org/src/${MY_P}.tar.gz"
+
+LICENSE="AGPL-3 Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="debug kerberos libressl mms-agent ssl test +tools"
+
+RDEPEND=">=app-arch/snappy-1.1.3
+	>=dev-cpp/yaml-cpp-0.5.3:=
+	>=dev-libs/boost-1.60:=[threads(+)]
+	>=dev-libs/libpcre-8.41[cxx]
+	dev-libs/snowball-stemmer
+	net-libs/libpcap
+	>=sys-libs/zlib-1.2.8:=
+	kerberos? ( dev-libs/cyrus-sasl[kerberos] )
+	mms-agent? ( app-admin/mms-agent )
+	ssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1g:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-util/scons
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	debug? ( dev-util/valgrind )
+	test? (
+		dev-python/pymongo[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)"
+PDEPEND="tools? ( >=app-admin/mongo-tools-${PV} )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.4.0-fix-scons.patch"
+	"${FILESDIR}/${PN}-3.4.6-sysmacros-include.patch"
+	"${FILESDIR}/${PN}-3.4.7-no-boost-check.patch"
+)
+
+S=${WORKDIR}/${MY_P}
+
+pkg_pretend() {
+	if [[ -n ${REPLACING_VERSIONS} ]]; then
+		if ver_test "$REPLACING_VERSIONS" -lt 3.2; then
+			ewarn "To upgrade from a version earlier than the 3.2-series, you must"
+			ewarn "successively upgrade major releases until you have upgraded"
+			ewarn "to 3.2-series. Then upgrade to 3.4 series."
+		fi
+	fi
+}
+
+pkg_setup() {
+	enewgroup mongodb
+	enewuser mongodb -1 -1 /var/lib/${PN} mongodb
+
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# remove bundled libs
+	rm -r src/third_party/{boost-*,pcre-*,scons-*,snappy-*,yaml-cpp-*,zlib-*} || die
+}
+
+src_configure() {
+	# https://github.com/mongodb/mongo/wiki/Build-Mongodb-From-Source
+	# --use-system-icu fails tests
+	# --use-system-tcmalloc is strongly NOT recommended:
+	scons_opts=(
+		CC="$(tc-getCC)"
+		CXX="$(tc-getCXX)"
+
+		--disable-warnings-as-errors
+		--use-system-boost
+		--use-system-pcre
+		--use-system-snappy
+		--use-system-stemmer
+		--use-system-yaml
+		--use-system-zlib
+	)
+
+	use debug && scons_opts+=( --dbg=on )
+	use kerberos && scons_opts+=( --use-sasl-client )
+	use ssl && scons_opts+=( --ssl )
+
+	# respect mongoDB upstream's basic recommendations
+	# see bug #536688 and #526114
+	if ! use debug; then
+		filter-flags '-m*'
+		filter-flags '-O?'
+	fi
+
+	default
+}
+
+src_compile() {
+	escons "${scons_opts[@]}" core tools
+}
+
+# FEATURES="test -usersandbox" emerge dev-db/mongodb
+src_test() {
+	# this one test fails
+	rm jstests/core/jsHeapLimit.js || die
+
+	"${EPYTHON}" ./buildscripts/resmoke.py --dbpathPrefix=test --suites core --jobs=$(makeopts_jobs) || die "Tests failed"
+}
+
+src_install() {
+	escons "${scons_opts[@]}" --nostrip install --prefix="${ED}"/usr
+
+	doman debian/mongo*.1
+	dodoc README docs/building.md
+
+	newinitd "${FILESDIR}/${PN}.initd-r3" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd-r3" ${PN}
+	newinitd "${FILESDIR}/mongos.initd-r3" ${PN/db/s}
+	newconfd "${FILESDIR}/mongos.confd-r3" ${PN/db/s}
+
+	insinto /etc
+	newins "${FILESDIR}/${PN}.conf-r3" ${PN}.conf
+	newins "${FILESDIR}/mongos.conf-r2" ${PN/db/s}.conf
+
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	insinto /etc/logrotate.d/
+	newins "${FILESDIR}/${PN}.logrotate" ${PN}
+
+	# see bug #526114
+	pax-mark emr "${ED}"/usr/bin/{mongo,mongod,mongos}
+
+	local x
+	for x in /var/{lib,log}/${PN}; do
+		diropts -m0750 -o mongodb -g mongodb
+		keepdir "${x}"
+	done
+}
+
+pkg_postinst() {
+	ewarn "Make sure to read the release notes and follow the upgrade process:"
+	ewarn "  https://docs.mongodb.com/manual/release-notes/$(ver_cut 1-2)/"
+	ewarn "  https://docs.mongodb.com/manual/release-notes/$(ver_cut 1-2)/#upgrade-procedures"
+}